termux-app/terminal-emulator/build.gradle

plugins {
    id "com.jfrog.bintray" version "1.7.3"
    id "com.github.dcendents.android-maven" version "2.0"
}

apply plugin: 'com.android.library'

ext {
    bintrayName = 'terminal-emulator'
    publishedGroupId = 'com.termux'
    libraryName = 'TerminalEmulator'
    artifact = 'terminal-emulator'
    libraryDescription = 'The terminal emulator used in Termux'
    siteUrl = 'https://github.com/termux/termux'
    gitUrl = 'https://github.com/termux/termux.git'
    libraryVersion = '0.52'
}

android {
    compileSdkVersion 27
    buildToolsVersion "27.0.1"

    defaultConfig {
        minSdkVersion 21
        targetSdkVersion 27

        externalNativeBuild {
            ndkBuild {
                cFlags "-std=c11", "-Wall", "-Wextra", "-Werror", "-Os", "-fno-stack-protector", "-Wl,--gc-sections"
            }
        }

        ndk {
            abiFilters 'x86', 'x86_64', 'armeabi-v7a', 'arm64-v8a'
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }

    externalNativeBuild {
        ndkBuild {
            path "src/main/jni/Android.mk"
        }
    }
}

tasks.withType(Test) {
    testLogging {
        events "started", "passed", "skipped", "failed"
    }
}

dependencies {
    testCompile 'junit:junit:4.12'
}

apply from: '../scripts/bintray-publish.gradle'