https://github.com/akkartik/mu/blob/main/121new-stream.subx

      1 # Helper to allocate a stream on the heap.
      2
      3 == code
      4 #   instruction                     effective address                                                   register    displacement    immediate
      5 # . op          subop               mod             rm32          base        index         scale       r32
      6 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
      7
      8 new-stream:  # ad: (addr allocation-descriptor), length: int, elemsize: int, out: (addr handle stream _)
      9     # . prologue
     10     55/push-ebp
     11     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
     12     # . save registers
     13     50/push-eax
     14     52/push-edx
     15     # var size/edx: int = elemsize*length (clobbering eax)
     16     # . eax = elemsize
     17     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           0/r32/eax   0x10/disp8      .                 # copy *(ebp+16) to eax
     18     # . eax *= length
     19     31/xor                          3/mod/direct    2/rm32/edx    .           .             .           2/r32/edx   .               .                 # clear edx
     20     f7          4/subop/multiply    1/mod/*+disp8   5/rm32/ebp    .           .                                     0xc/disp8       .                 # multiply *(ebp+12) into edx:eax
     21     # . if overflow abort
     22     81          7/subop/compare     3/mod/direct    2/rm32/edx    .           .             .           .           .               0/imm32           # compare edx
     23     75/jump-if-!=  $new-stream:abort/disp8
     24     # . edx = elemsize*length
     25     89/copy                         3/mod/direct    2/rm32/edx    .           .             .           0/r32/eax   .               .                 # copy eax to edx
     26     # var n/eax: int = size + 12 (for read, write and size)
     27     05/add-to-eax  0xc/imm32
     28     # allocate(ad, n, out)
     29     # . . push args
     30     ff          6/subop/push        1/mod/*+disp8   5/rm32/ebp    .           .             .           .           0x14/disp8      .                 # push *(ebp+20)
     31     50/push-eax
     32     ff          6/subop/push        1/mod/*+disp8   5/rm32/ebp    .           .             .           .           8/disp8         .                 # push *(ebp+8)
     33     # . . call
     34     e8/call  allocate/disp32
     35     # . . discard args
     36     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
     37     # eax = out->payload
     38     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           0/r32/eax   0x14/disp8      .                 # copy *(ebp+20) to eax
     39     8b/copy                         1/mod/*+disp8   0/rm32/eax    .           .             .           0/r32/eax   4/disp8         .                 # copy *(eax+4) to eax
     40     # skip payload->allocid
     41     05/add-to-eax  4/imm32
     42     # eax->size = size
     43     89/copy                         1/mod/*+disp8   0/rm32/eax    .           .             .           2/r32/edx   8/disp8         .                 # copy edx to *(eax+8)
     44     # clear-stream(eax)
     45     # . . push args
     46     50/push-eax
     47     # . . call
     48     e8/call  clear-stream/disp32
     49     # . . discard args
     50     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
     51 $new-stream:end:
     52     # . restore registers
     53     5a/pop-to-edx
     54     58/pop-to-eax
     55     # . epilogue
     56     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
     57     5d/pop-to-ebp
     58     c3/return
     59
     60 $new-stream:abort:
     61     (draw-text-wrapping-right-then-down-from-cursor-over-full-screen 0 "new-stream: size too large" 3 0)  # 3=cyan
     62     {
     63       eb/jump loop/disp8
     64     }
     65     # never gets here
     66
     67 test-new-stream:
     68     # . prologue
     69     55/push-ebp
     70     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
     71     # var ad/ecx: allocation-descriptor containing 16 bytes
     72     # . var end/ecx: (addr byte)
     73     89/<- %ecx 4/r32/esp
     74     # . var start/edx: (addr byte) = end - 32
     75     81 5/subop/subtract %esp 0x20/imm32
     76     89/<- %edx 4/r32/esp
     77     # . ad = {start, end}
     78     51/push-ecx
     79     52/push-edx
     80     89/copy                         3/mod/direct    1/rm32/ecx    .           .             .           4/r32/esp   .               .                 # copy esp to ecx
     81     # var start/edx = ad->curr
     82     8b/copy                         0/mod/indirect  1/rm32/ecx    .           .             .           2/r32/edx   .               .                 # copy *ecx to edx
     83     # var h/ebx: (handle stream byte)
     84     68/push  0/imm32
     85     68/push  0/imm32
     86     89/copy                         3/mod/direct    3/rm32/ebx    .           .             .           4/r32/esp   .               .                 # copy esp to ebx
     87     # new-stream(ad, 3, 2, h)
     88     # . . push args
     89     53/push-ebx
     90     68/push  2/imm32
     91     68/push  3/imm32
     92     51/push-ecx
     93     # . . call
     94     e8/call  new-stream/disp32
     95     # . . discard args
     96     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0x10/imm32        # add to esp
     97     # eax = out->payload
     98     8b/copy                         1/mod/*+disp8   3/rm32/ebx    .           .             .           0/r32/eax   4/disp8         .                 # copy *(ebx+4) to eax
     99     # check-ints-equal(eax, edx, msg)
    100     # . . push args
    101     68/push  "F - test-new-stream: returns current pointer of allocation descriptor"/imm32
    102     52/push-edx
    103     50/push-eax
    104     # . . call
    105     e8/call  check-ints-equal/disp32
    106     # . . discard args
    107     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
    108     # skip payload->allocid
    109     05/add-to-eax  4/imm32
    110     # check-ints-equal(eax->size, 6, msg)
    111     # . . push args
    112     68/push  "F - test-new-stream: sets size correctly"/imm32
    113     68/push  6/imm32
    114     ff          6/subop/push        1/mod/*+disp8   0/rm32/eax    .           .             .           .           .               8/disp8           # push *(eax+8)
    115     # . . call
    116     e8/call  check-ints-equal/disp32
    117     # . . discard args
    118     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
    119     # the rest is delegated to clear-stream() so we won't bother checking it
    120     # . reclaim locals
    121     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0x30/imm32        # add to esp
    122     # . epilogue
    123     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
    124     5d/pop-to-ebp
    125     c3/return
    126
    127 # . . vim:nowrap:textwidth=0