# Mu - subx/examples/ex8.subx

     1 ## Example reading commandline arguments: compute length of first arg.
     2 #
     3 # To run (from the subx directory):
     4 #   $ subx translate examples/ex8.subx -o examples/ex8
     5 #   $ subx run examples/ex8 abc de fghi
     6 # Expected result:
     7 #   $ echo $?
     8 #   3  # length of 'abc'
     9 #
    10 # At the start of a SubX program:
    11 #   argc: *ESP
    12 #   argv[0]: *(ESP+4)
    13 #   argv[1]: *(ESP+8)
    14 #   ...
    15 # Locals start from ESP-4 downwards.
    16
    17 == code
    18 # instruction                     effective address                                                   operand     displacement    immediate
    19 # op          subop               mod             rm32          base        index         scale       r32
    20 # 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
    21   # prolog
    22   89/copy                         3/mod/direct    5/rm32/EBP    .           .             .           4/r32/ESP   .               .                 # copy ESP to EBP
    23   # call ascii-length(argv[1])
    24     # push args
    25   ff          6/subop/push        1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           .           0x8/disp8       .                 # push *(EBP+8)
    26     # call
    27   e8/call  ascii-length/disp32
    28     # discard args
    29   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
    30
    31   # exit(EAX)
    32   89/copy                         3/mod/direct    3/rm32/EBX    .           .             .           0/r32/EAX   .               .                 # copy EAX to EBX
    33   b8/copy-to-EAX  1/imm32/exit
    34   cd/syscall  0x80/imm8
    35
    36 ascii-length:  # (s)
    37   # initialize s (EDX)
    38   8b/copy                         1/mod/*+disp8   4/rm32/sib    4/base/ESP  4/index/none  .           2/r32/EDX   4/disp8         .                 # copy *(ESP+4) to EDX
    39   # var result = 0 (EAX)
    40   b8/copy-to-EAX  0/imm32
    41 $ascii-length-loop:
    42   # var c = *s (ECX)
    43   8a/copy                         0/mod/*         2/rm32/EDX    .           .             .           1/r32/ECX   .               .                 # copy byte at *EDX to lower byte of ECX
    44   # if c == '\0' break
    45   81          7/subop/compare     3/mod/direct    1/rm32/ECX    .           .             .           .           .               0/imm32           # compare ECX
    46   74/jump-if-equal  $ascii-length-ret/disp8
    47   # ++s
    48   81          0/subop/add         3/mod/direct    2/rm32/EDX    .           .             .           .           .               1/imm32           # add to EDX
    49   # ++result
    50   40/inc-EAX
    51   # loop
    52   eb/jump  $ascii-length-loop/disp8
    53 $ascii-length-ret:
    54   # return (result in EAX)
    55   c3/return
    56
    57 # vim:nowrap:textwidth=0