# Mu - subx/examples/ex11.subx

      1 ## Null-terminated vs length-prefixed ascii strings.
      2 #
      3 # By default we create strings with a 4-byte length prefix rather than a null suffix.
      4 # However we still need null-prefixed strings when interacting with the Linux
      5 # kernel in a few places. This layer implements a function for comparing
      6 # a null-terminated 'kernel string' with a length-prefixed 'SubX string'.
      7 #
      8 # To run (from the subx directory):
      9 #   $ subx translate examples/ex11.subx -o examples/ex11
     10 #   $ subx run examples/ex11  # runs a series of tests
     11 #   ......  # all tests pass
     12 #
     13 # (We can't yet run the tests when given a "test" commandline argument,
     14 # because checking for it would require the function being tested! Breakage
     15 # would cause tests to not run, rather than to fail as we'd like.)
     16
     17 == code
     18
     19 # instruction                     effective address                                                   operand     displacement    immediate
     20 # op          subop               mod             rm32          base        index         scale       r32
     21 # 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
     22
     23 # main:
     24   e8/call  run-tests/disp32  # 'run-tests' is a function created automatically by SubX. It calls all functions that start with 'test-'.
     25   # syscall(exit, EAX)
     26   89/copy                         3/mod/direct    3/rm32/EBX    .           .             .           0/r32/EAX   .               .                 # copy EAX to EBX
     27   b8/copy-to-EAX  1/imm32
     28   cd/syscall  0x80/imm8
     29
     30 # compare a null-terminated ascii string with a more idiomatic length-prefixed byte array
     31 # reason for the name: the only place we should have null-terminated ascii strings is from commandline args
     32 kernel-string-equal:  # s : null-terminated ascii string, benchmark : length-prefixed ascii string -> EAX : boolean
     33   # prolog
     34   55/push-EBP
     35   89/copy                         3/mod/direct    5/rm32/EBP    .           .             .           4/r32/ESP   .               .                 # copy ESP to EBP
     36   # save registers
     37   51/push-ECX
     38   52/push-EDX
     39   53/push-EBX
     40   56/push-ESI
     41   57/push-EDI
     42
     43   # pseudocode:
     44   #   initialize n = b.length
     45   #   initialize s1 = s
     46   #   initialize s2 = b.data
     47   #   i = 0
     48   #   for (i = 0; i < n; ++n)
     49   #     c1 = *s1
     50   #     c2 = *s2
     51   #     if c1 == 0
     52   #       return false
     53   #     if c1 != c2
     54   #       return false
     55   #   return *s1 == 0
     56   # initialize s into EDI
     57   8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           7/r32/EDI   8/disp8         .                 # copy *(EBP+8) to EDI
     58   # initialize benchmark length n into EDX
     59   8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           2/r32/EDX   0xc/disp8       .                 # copy *(EBP+12) to EDX
     60   8b/copy                         0/mod/indirect  2/rm32/EDX    .           .             .           2/r32/EDX   .               .                 # copy *EDX to EDX
     61   # initialize benchmark data into ESI
     62   8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           6/r32/ESI   0xc/disp8       .                 # copy *(EBP+12) to ESI
     63   81          0/subop/add         3/mod/direct    6/rm32/ESI    .           .             .           .           .               4/imm32           # add to ESI
     64   # initialize loop counter i into ECX
     65   b9/copy-to-ECX  0/imm32/exit
     66   # while (i/ECX < n/EDX)
     67 $kernel-string-equal:loop:
     68   39/compare                      3/mod/direct    1/rm32/ECX    .           .             .           2/r32/EDX   .               .                 # compare ECX with EDX
     69   74/jump-if-equal  $kernel-string-equal:break/disp8
     70     # c1/EAX, c2/EBX = *s, *benchmark
     71   b8/copy-to-EAX  0/imm32
     72   8a/copy                         0/mod/indirect  7/rm32/EDI    .           .             .           0/r32/EAX   .               .                 # copy byte at *EDI to lower byte of EAX
     73   bb/copy-to-EBX  0/imm32
     74   8a/copy                         0/mod/indirect  6/rm32/ESI    .           .             .           3/r32/EBX   .               .                 # copy byte at *ESI to lower byte of EBX
     75     # if (c1 == 0) return false
     76   3d/compare-EAX  0/imm32
     77   74/jump-if-equal  $kernel-string-equal:false/disp8
     78     # if (c1 != c2) return false
     79   39/compare                      3/mod/direct    0/rm32/EAX    .           .             .           3/r32/EBX   .               .                 # compare EAX with EBX
     80   75/jump-if-not-equal  $kernel-string-equal:false/disp8
     81     # ++s1, ++s2, ++i
     82   41/inc-ECX
     83   46/inc-ESI
     84   47/inc-EDI
     85   # end while
     86   eb/jump  $kernel-string-equal:loop/disp8
     87 $kernel-string-equal:break:
     88   # if (*s/EDI == 0) return true
     89   b8/copy-to-EAX  0/imm32
     90   8a/copy                         0/mod/indirect  7/rm32/EDI    .           .             .           0/r32/EAX   .               .                 # copy byte at *EDI to lower byte of EAX
     91   81          7/subop/compare     3/mod/direct    0/rm32/EAX    .           .             .           .           .               0/imm32           # compare EAX
     92   75/jump-if-not-equal  $kernel-string-equal:false/disp8
     93   b8/copy-to-EAX  1/imm32
     94 $kernel-string-equal:true:
     95   eb/jump  $kernel-string-equal:end/disp8
     96   # return false
     97 $kernel-string-equal:false:
     98   b8/copy-to-EAX  0/imm32
     99
    100 $kernel-string-equal:end:
    101   # restore registers
    102   5f/pop-to-EDI
    103   5e/pop-to-ESI
    104   5b/pop-to-EBX
    105   5a/pop-to-EDX
    106   59/pop-to-ECX
    107   # end
    108   89/copy                         3/mod/direct    4/rm32/ESP    .           .             .           5/r32/EBP   .               .                 # copy EBP to ESP
    109   5d/pop-to-EBP
    110   c3/return
    111
    112 ## tests
    113
    114 test-compare-null-kernel-string-with-empty-array:
    115   # EAX = kernel-string-equal(Null-kernel-string, "")
    116     # push args
    117   68/push  ""/imm32
    118   68/push  Null-kernel-string/imm32
    119     # call
    120   e8/call  kernel-string-equal/disp32
    121     # discard args
    122   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
    123   # call check-ints-equal(EAX, 1, msg)
    124     # push args
    125   68/push  "F - test-compare-null-kernel-string-with-empty-array"/imm32
    126   68/push  1/imm32/true
    127   50/push-EAX
    128     # call
    129   e8/call  check-ints-equal/disp32
    130     # discard args
    131   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
    132   c3/return
    133
    134 test-compare-null-kernel-string-with-non-empty-array:
    135   # EAX = kernel-string-equal(Null-kernel-string, "Abc")
    136     # push args
    137   68/push  "Abc"/imm32
    138   68/push  Null-kernel-string/imm32
    139     # call
    140   e8/call  kernel-string-equal/disp32
    141     # discard args
    142   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
    143   # call check-ints-equal(EAX, 0, msg)
    144     # push args
    145   68/push  "F - test-compare-null-kernel-string-with-non-empty-array"/imm32
    146   68/push  0/imm32/false
    147   50/push-EAX
    148     # call
    149   e8/call  check-ints-equal/disp32
    150     # discard args
    151   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
    152   c3/return
    153
    154 test-compare-kernel-string-with-equal-array:
    155   # EAX = kernel-string-equal(Abc-kernel-string, "Abc")
    156     # push args
    157   68/push  "Abc"/imm32
    158   68/push  Abc-kernel-string/imm32
    159     # call
    160   e8/call  kernel-string-equal/disp32
    161     # discard args
    162   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
    163   # call check-ints-equal(EAX, 1, msg)
    164     # push args
    165   68/push  "F - test-compare-kernel-string-with-equal-array"/imm32
    166   68/push  1/imm32/true
    167   50/push-EAX
    168     # call
    169   e8/call  check-ints-equal/disp32
    170     # discard args
    171   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
    172   c3/return
    173
    174 test-compare-kernel-string-with-inequal-array:
    175   # EAX = kernel-string-equal(Abc-kernel-string, "Adc")
    176     # push args
    177   68/push  "Adc"/imm32
    178   68/push  Abc-kernel-string/imm32
    179     # call
    180   e8/call  kernel-string-equal/disp32
    181     # discard args
    182   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
    183   # call check-ints-equal(EAX, 0, msg)
    184     # push args
    185   68/push  "F - test-compare-kernel-string-with-equal-array"/imm32
    186   68/push  0/imm32/false
    187   50/push-EAX
    188     # call
    189   e8/call  check-ints-equal/disp32
    190     # discard args
    191   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
    192   c3/return
    193
    194 test-compare-kernel-string-with-empty-array:
    195   # EAX = kernel-string-equal(Abc-kernel-string, "")
    196     # push args
    197   68/push  ""/imm32
    198   68/push  Abc-kernel-string/imm32
    199     # call
    200   e8/call  kernel-string-equal/disp32
    201     # discard args
    202   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
    203   # call check-ints-equal(EAX, 0)
    204     # push args
    205   68/push  "F - test-compare-kernel-string-with-equal-array"/imm32
    206   68/push  0/imm32/false
    207   50/push-EAX
    208     # call
    209   e8/call  check-ints-equal/disp32
    210     # discard args
    211   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
    212   c3/return
    213
    214 test-compare-kernel-string-with-shorter-array:
    215   # EAX = kernel-string-equal(Abc-kernel-string, "Ab")
    216     # push args
    217   68/push  "Ab"/imm32
    218   68/push  Abc-kernel-string/imm32
    219     # call
    220   e8/call  kernel-string-equal/disp32
    221     # discard args
    222   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
    223   # call check-ints-equal(EAX, 0)
    224     # push args
    225   68/push  "F - test-compare-kernel-string-with-shorter-array"/imm32
    226   68/push  0/imm32/false
    227   50/push-EAX
    228     # call
    229   e8/call  check-ints-equal/disp32
    230     # discard args
    231   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
    232   c3/return
    233
    234 test-compare-kernel-string-with-longer-array:
    235   # EAX = kernel-string-equal(Abc-kernel-string, "Abcd")
    236     # push args
    237   68/push  "Abcd"/imm32
    238   68/push  Abc-kernel-string/imm32
    239     # call
    240   e8/call  kernel-string-equal/disp32
    241     # discard args
    242   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
    243   # call check-ints-equal(EAX, 0)
    244     # push args
    245   68/push  "F - test-compare-kernel-string-with-longer-array"/imm32
    246   68/push  0/imm32/false
    247   50/push-EAX
    248     # call
    249   e8/call  check-ints-equal/disp32
    250     # discard args
    251   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
    252   c3/return
    253
    254 ## helpers
    255
    256 # print msg to stderr if a != b, otherwise print "."
    257 check-ints-equal:  # (a : int, b : int, msg : (address array byte)) -> boolean
    258   # prolog
    259   55/push-EBP
    260   89/copy                         3/mod/direct    5/rm32/EBP    .           .             .           4/r32/ESP   .               .                 # copy ESP to EBP
    261   # save registers
    262   51/push-ECX
    263   53/push-EBX
    264   # load args into EAX, EBX and ECX
    265   8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           0/r32/EAX   0x8/disp8       .                 # copy *(EBP+8) to EAX
    266   8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           3/r32/EBX   0xc/disp8       .                 # copy *(EBP+12) to EBX
    267   # if EAX == b/EBX
    268   39/compare                      3/mod/direct    0/rm32/EAX    .           .             .           3/r32/EBX   .               .                 # compare EAX and EBX
    269   75/jump-if-unequal  $check-ints-equal:else/disp8
    270     # print('.')
    271       # push args
    272   68/push  "."/imm32
    273       # call
    274   e8/call  write-stderr/disp32
    275       # discard args
    276   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
    277     # return
    278   eb/jump  $check-ints-equal:end/disp8
    279   # else:
    280 $check-ints-equal:else:
    281   # copy msg into ECX
    282   8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           1/r32/ECX   0x10/disp8       .                # copy *(EBP+16) to ECX
    283     # print(ECX)
    284       # push args
    285   51/push-ECX
    286       # call
    287   e8/call  write-stderr/disp32
    288       # discard args
    289   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
    290     # print newline
    291       # push args
    292   68/push  Newline/imm32
    293       # call
    294   e8/call  write-stderr/disp32
    295       # discard args
    296   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
    297 $check-ints-equal:end:
    298   # restore registers
    299   5b/pop-to-EBX
    300   59/pop-to-ECX
    301   # end
    302   89/copy                         3/mod/direct    4/rm32/ESP    .           .             .           5/r32/EBP   .               .                 # copy EBP to ESP
    303   5d/pop-to-EBP
    304   c3/return
    305
    306 write-stderr:  # s : (address array byte) -> <void>
    307   # prolog
    308   55/push-EBP
    309   89/copy                         3/mod/direct    5/rm32/EBP    .           .             .           4/r32/ESP   .               .                 # copy ESP to EBP
    310   # save registers
    311   50/push-EAX
    312   51/push-ECX
    313   52/push-EDX
    314   53/push-EBX
    315   # syscall(write, 2/stderr, (data) s+4, (size) *s)
    316     # fd = 2 (stderr)
    317   bb/copy-to-EBX  2/imm32
    318     # x = s+4
    319   8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           1/r32/ECX   8/disp8         .                 # copy *(EBP+8) to ECX
    320   81          0/subop/add         3/mod/direct    1/rm32/ECX    .           .             .           .           .               4/imm32           # add to ECX
    321     # size = *s
    322   8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           2/r32/EDX   8/disp8         .                 # copy *(EBP+8) to EDX
    323   8b/copy                         0/mod/indirect  2/rm32/EDX    .           .             .           2/r32/EDX   .               .                 # copy *EDX to EDX
    324     # syscall
    325   b8/copy-to-EAX  4/imm32/write
    326   cd/syscall  0x80/imm8
    327   # restore registers
    328   5b/pop-to-EBX
    329   5a/pop-to-EDX
    330   59/pop-to-ECX
    331   58/pop-to-EAX
    332   # end
    333   89/copy                         3/mod/direct    4/rm32/ESP    .           .             .           5/r32/EBP   .               .                 # copy EBP to ESP
    334   5d/pop-to-EBP
    335   c3/return
    336
    337 == data
    338 Newline:
    339   # size
    340   01 00 00 00
    341   # data
    342   0a/newline
    343
    344 # for kernel-string-equal tests
    345 Null-kernel-string:
    346   00/null
    347 Abc-kernel-string:
    348   41/A 62/b 63/c 00/null
    349
    350 # vim:nowrap:textwidth=0