# Mu - subx/052kernel_string_equal.subx

      1 ## Checking null-terminated ascii strings.
      2 #
      3 # By default we create strings with a 4-byte length prefix rather than a null suffix.
      4 # However we still need null-prefixed strings when interacting with the Linux
      5 # kernel in a few places. This layer implements a function for comparing
      6 # a null-terminated 'kernel string' with a length-prefixed 'SubX string'.
      7 #
      8 # To run (from the subx directory):
      9 #   $ subx translate 05[0-2]*.subx -o /tmp/tmp52
     10 #   $ subx run /tmp/tmp52  # runs a series of tests
     11 #   ......  # all tests pass
     12 #
     13 # (We can't yet run the tests when given a "test" commandline argument,
     14 # because checking for it would require the function being tested! Breakage
     15 # would cause tests to not run, rather than to fail as we'd like.)
     16
     17 == code
     18
     19 # instruction                     effective address                                                   operand     displacement    immediate
     20 # op          subop               mod             rm32          base        index         scale       r32
     21 # 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
     22
     23 # main:  (manual test if this is the last file loaded)
     24   e8/call  run-tests/disp32  # 'run-tests' is a function created automatically by SubX. It calls all functions that start with 'test-'.
     25   # exit(Num-test-failures)
     26   8b/copy                         0/mod/indirect  5/rm32/.disp32            .             .           3/r32/EBX   Num-test-failures/disp32          # copy *Num-test-failures to EBX
     27   b8/copy-to-EAX  1/imm32
     28   cd/syscall  0x80/imm8
     29
     30 # compare a null-terminated ascii string with a more idiomatic length-prefixed byte array
     31 # reason for the name: the only place we should have null-terminated ascii strings is from commandline args
     32 kernel-string-equal:  # s : null-terminated ascii string, benchmark : length-prefixed ascii string -> EAX : boolean
     33   # prolog
     34   55/push-EBP
     35   89/copy                         3/mod/direct    5/rm32/EBP    .           .             .           4/r32/ESP   .               .                 # copy ESP to EBP
     36   # save registers
     37   51/push-ECX
     38   52/push-EDX
     39   53/push-EBX
     40   56/push-ESI
     41   57/push-EDI
     42
     43   # pseudocode:
     44   #   initialize n = b.length
     45   #   initialize s1 = s
     46   #   initialize s2 = b.data
     47   #   i = 0
     48   #   for (i = 0; i < n; ++n)
     49   #     c1 = *s1
     50   #     c2 = *s2
     51   #     if c1 == 0
     52   #       return false
     53   #     if c1 != c2
     54   #       return false
     55   #   return *s1 == 0
     56   #
     57   # initialize s into EDI
     58   8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           7/r32/EDI   8/disp8         .                 # copy *(EBP+8) to EDI
     59   # initialize benchmark length n into EDX
     60   8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           2/r32/EDX   0xc/disp8       .                 # copy *(EBP+12) to EDX
     61   8b/copy                         0/mod/indirect  2/rm32/EDX    .           .             .           2/r32/EDX   .               .                 # copy *EDX to EDX
     62   # initialize benchmark data into ESI
     63   8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           6/r32/ESI   0xc/disp8       .                 # copy *(EBP+12) to ESI
     64   81          0/subop/add         3/mod/direct    6/rm32/ESI    .           .             .           .           .               4/imm32           # add to ESI
     65   # initialize loop counter i into ECX
     66   b9/copy-to-ECX  0/imm32/exit
     67   # while (i/ECX < n/EDX)
     68 $kernel-string-equal:loop:
     69   39/compare                      3/mod/direct    1/rm32/ECX    .           .             .           2/r32/EDX   .               .                 # compare ECX with EDX
     70   74/jump-if-equal  $kernel-string-equal:break/disp8
     71     # c1/EAX, c2/EBX = *s, *benchmark
     72   b8/copy-to-EAX  0/imm32
     73   8a/copy                         0/mod/indirect  7/rm32/EDI    .           .             .           0/r32/EAX   .               .                 # copy byte at *EDI to lower byte of EAX
     74   bb/copy-to-EBX  0/imm32
     75   8a/copy                         0/mod/indirect  6/rm32/ESI    .           .             .           3/r32/EBX   .               .                 # copy byte at *ESI to lower byte of EBX
     76     # if (c1 == 0) return false
     77   3d/compare-EAX  0/imm32
     78   74/jump-if-equal  $kernel-string-equal:false/disp8
     79     # if (c1 != c2) return false
     80   39/compare                      3/mod/direct    0/rm32/EAX    .           .             .           3/r32/EBX   .               .                 # compare EAX with EBX
     81   75/jump-if-not-equal  $kernel-string-equal:false/disp8
     82     # ++s1, ++s2, ++i
     83   41/inc-ECX
     84   46/inc-ESI
     85   47/inc-EDI
     86   # end while
     87   eb/jump  $kernel-string-equal:loop/disp8
     88 $kernel-string-equal:break:
     89   # if (*s/EDI == 0) return true
     90   b8/copy-to-EAX  0/imm32
     91   8a/copy                         0/mod/indirect  7/rm32/EDI    .           .             .           0/r32/EAX   .               .                 # copy byte at *EDI to lower byte of EAX
     92   3d/compare-EAX  0/imm32
     93   75/jump-if-not-equal  $kernel-string-equal:false/disp8
     94 $kernel-string-equal:true:
     95   b8/copy-to-EAX  1/imm32
     96   eb/jump  $kernel-string-equal:end/disp8
     97   # return false
     98 $kernel-string-equal:false:
     99   b8/copy-to-EAX  0/imm32
    100
    101 $kernel-string-equal:end:
    102   # restore registers
    103   5f/pop-to-EDI
    104   5e/pop-to-ESI
    105   5b/pop-to-EBX
    106   5a/pop-to-EDX
    107   59/pop-to-ECX
    108   # epilog
    109   89/copy                         3/mod/direct    4/rm32/ESP    .           .             .           5/r32/EBP   .               .                 # copy EBP to ESP
    110   5d/pop-to-EBP
    111   c3/return
    112
    113 ## tests
    114
    115 test-compare-null-kernel-string-with-empty-array:
    116   # EAX = kernel-string-equal(Null-kernel-string, "")
    117     # push args
    118   68/push  ""/imm32
    119   68/push  Null-kernel-string/imm32
    120     # call
    121   e8/call  kernel-string-equal/disp32
    122     # discard args
    123   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
    124   # call check-ints-equal(EAX, 1, msg)
    125     # push args
    126   68/push  "F - test-compare-null-kernel-string-with-empty-array"/imm32
    127   68/push  1/imm32/true
    128   50/push-EAX
    129     # call
    130   e8/call  check-ints-equal/disp32
    131     # discard args
    132   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
    133   c3/return
    134
    135 test-compare-null-kernel-string-with-non-empty-array:
    136   # EAX = kernel-string-equal(Null-kernel-string, "Abc")
    137     # push args
    138   68/push  "Abc"/imm32
    139   68/push  Null-kernel-string/imm32
    140     # call
    141   e8/call  kernel-string-equal/disp32
    142     # discard args
    143   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
    144   # call check-ints-equal(EAX, 0, msg)
    145     # push args
    146   68/push  "F - test-compare-null-kernel-string-with-non-empty-array"/imm32
    147   68/push  0/imm32/false
    148   50/push-EAX
    149     # call
    150   e8/call  check-ints-equal/disp32
    151     # discard args
    152   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
    153   c3/return
    154
    155 test-compare-kernel-string-with-equal-array:
    156   # EAX = kernel-string-equal(Abc-kernel-string, "Abc")
    157     # push args
    158   68/push  "Abc"/imm32
    159   68/push  Abc-kernel-string/imm32
    160     # call
    161   e8/call  kernel-string-equal/disp32
    162     # discard args
    163   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
    164   # call check-ints-equal(EAX, 1, msg)
    165     # push args
    166   68/push  "F - test-compare-kernel-string-with-equal-array"/imm32
    167   68/push  1/imm32/true
    168   50/push-EAX
    169     # call
    170   e8/call  check-ints-equal/disp32
    171     # discard args
    172   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
    173   c3/return
    174
    175 test-compare-kernel-string-with-inequal-array:
    176   # EAX = kernel-string-equal(Abc-kernel-string, "Adc")
    177     # push args
    178   68/push  "Adc"/imm32
    179   68/push  Abc-kernel-string/imm32
    180     # call
    181   e8/call  kernel-string-equal/disp32
    182     # discard args
    183   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
    184   # call check-ints-equal(EAX, 0, msg)
    185     # push args
    186   68/push  "F - test-compare-kernel-string-with-equal-array"/imm32
    187   68/push  0/imm32/false
    188   50/push-EAX
    189     # call
    190   e8/call  check-ints-equal/disp32
    191     # discard args
    192   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
    193   c3/return
    194
    195 test-compare-kernel-string-with-empty-array:
    196   # EAX = kernel-string-equal(Abc-kernel-string, "")
    197     # push args
    198   68/push  ""/imm32
    199   68/push  Abc-kernel-string/imm32
    200     # call
    201   e8/call  kernel-string-equal/disp32
    202     # discard args
    203   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
    204   # call check-ints-equal(EAX, 0)
    205     # push args
    206   68/push  "F - test-compare-kernel-string-with-equal-array"/imm32
    207   68/push  0/imm32/false
    208   50/push-EAX
    209     # call
    210   e8/call  check-ints-equal/disp32
    211     # discard args
    212   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
    213   c3/return
    214
    215 test-compare-kernel-string-with-shorter-array:
    216   # EAX = kernel-string-equal(Abc-kernel-string, "Ab")
    217     # push args
    218   68/push  "Ab"/imm32
    219   68/push  Abc-kernel-string/imm32
    220     # call
    221   e8/call  kernel-string-equal/disp32
    222     # discard args
    223   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
    224   # call check-ints-equal(EAX, 0)
    225     # push args
    226   68/push  "F - test-compare-kernel-string-with-shorter-array"/imm32
    227   68/push  0/imm32/false
    228   50/push-EAX
    229     # call
    230   e8/call  check-ints-equal/disp32
    231     # discard args
    232   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
    233   c3/return
    234
    235 test-compare-kernel-string-with-longer-array:
    236   # EAX = kernel-string-equal(Abc-kernel-string, "Abcd")
    237     # push args
    238   68/push  "Abcd"/imm32
    239   68/push  Abc-kernel-string/imm32
    240     # call
    241   e8/call  kernel-string-equal/disp32
    242     # discard args
    243   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
    244   # call check-ints-equal(EAX, 0)
    245     # push args
    246   68/push  "F - test-compare-kernel-string-with-longer-array"/imm32
    247   68/push  0/imm32/false
    248   50/push-EAX
    249     # call
    250   e8/call  check-ints-equal/disp32
    251     # discard args
    252   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
    253   c3/return
    254
    255 == data
    256
    257 Null-kernel-string:
    258   00/null
    259 Abc-kernel-string:
    260   41/A 62/b 63/c 00/null
    261
    262 # vim:nowrap:textwidth=0