shell: macroexpand outermost call

shell/global.mu

@@ -351,6 +351,28 @@ fn lookup-symbol-in-globals _sym: (addr cell), out: (addr handle cell), _globals
   trace trace, "error", stream
 }
 
+fn maybe-lookup-symbol-in-globals _sym: (addr cell), out: (addr handle cell), _globals: (addr global-table), trace: (addr trace) {
+  var sym/eax: (addr cell) <- copy _sym
+  var sym-name-ah/eax: (addr handle stream byte) <- get sym, text-data
+  var _sym-name/eax: (addr stream byte) <- lookup *sym-name-ah
+  var sym-name/edx: (addr stream byte) <- copy _sym-name
+  var globals/esi: (addr global-table) <- copy _globals
+  {
+    compare globals, 0
+    break-if-=
+    var curr-index/ecx: int <- find-symbol-in-globals globals, sym-name
+    compare curr-index, -1/not-found
+    break-if-=
+    var global-data-ah/eax: (addr handle array global) <- get globals, data
+    var global-data/eax: (addr array global) <- lookup *global-data-ah
+    var curr-offset/ebx: (offset global) <- compute-offset global-data, curr-index
+    var curr/ebx: (addr global) <- index global-data, curr-offset
+    var curr-value/eax: (addr handle cell) <- get curr, value
+    copy-object curr-value, out
+    return
+  }
+}
+
 # return the index in globals containing 'sym'
 # or -1 if not found
 fn find-symbol-in-globals _globals: (addr global-table), sym-name: (addr stream byte) -> _/ecx: int {

shell/macroexpand.mu

@@ -7,5 +7,47 @@ fn macroexpand expr-ah: (addr handle cell), globals: (addr global-table), trace:
 
 # return true if we found any macros
 fn macroexpand-iter _expr-ah: (addr handle cell), globals: (addr global-table), trace: (addr trace) -> _/eax: boolean {
-  return 0/false
+  # if car(expr) is a symbol defined as a macro, expand it
+  var expr-ah/esi: (addr handle cell) <- copy _expr-ah
+  var expr/eax: (addr cell) <- lookup *expr-ah
+  {
+    var expr-type/eax: (addr int) <- get expr, type
+    compare *expr-type, 0/pair
+    break-if-=
+    # not a pair
+    return 0/false
+  }
+  var first-ah/ebx: (addr handle cell) <- get expr, left
+  var rest-ah/ecx: (addr handle cell) <- get expr, right
+  var first/eax: (addr cell) <- lookup *first-ah
+  var definition-h: (handle cell)
+  var definition-ah/ebx: (addr handle cell) <- address definition-h
+  maybe-lookup-symbol-in-globals first, definition-ah, globals, trace
+  var definition/eax: (addr cell) <- lookup *definition-ah
+  compare definition, 0
+  {
+    break-if-!=
+    # no definition
+    return 0/false
+  }
+  {
+    var definition-type/eax: (addr int) <- get definition, type
+    compare *definition-type, 0/pair
+    break-if-=
+    # definition not a pair
+    return 0/false
+  }
+  {
+    var definition-car-ah/eax: (addr handle cell) <- get definition, left
+    var definition-car/eax: (addr cell) <- lookup *definition-car-ah
+    var macro?/eax: boolean <- litmac? definition-car
+    compare macro?, 0/false
+    break-if-!=
+    # definition not a macro
+    return 0/false
+  }
+  var macro-definition-ah/eax: (addr handle cell) <- get definition, right
+  # TODO: check car(macro-definition) is litfn
+  apply macro-definition-ah, rest-ah, expr-ah, globals, trace, 0/no-screen, 0/no-keyboard, 0/call-number
+  return 1/true
 }