1 # Rudimentary test harness
 2 
 3 == code
 4 #   instruction                     effective address                                                   register    displacement    immediate
 5 # . op          subop               mod             rm32          base        index         scale       r32
 6 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
 7 
 8 # main:  (manual test if this is the last file loaded)
 9     # check-ints-equal(34, 34)
10     # . . push args
11     68/push  "error in check-ints-equal"/imm32
12     68/push  34/imm32
13     68/push  34/imm32
14     # . . call
15     e8/call  check-ints-equal/disp32
16     # . . discard args
17     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
18     # syscall(exit, 0)
19     bb/copy-to-EBX  0/imm32
20     b8/copy-to-EAX  1/imm32/exit
21     cd/syscall  0x80/imm8
22 
23 # print msg to stderr if a != b, otherwise print "."
24 check-ints-equal:  # (a : int, b : int, msg : (address array byte)) -> <void>
25     # . prolog
26     55/push-EBP
27     89/copy                         3/mod/direct    5/rm32/EBP    .           .             .           4/r32/ESP   .               .                 # copy ESP to EBP
28     # . save registers
29     50/push-EAX
30     51/push-ECX
31     53/push-EBX
32     # load first 2 args into EAX and EBX
33     8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           0/r32/EAX   8/disp8         .                 # copy *(EBP+8) to EAX
34     8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           3/r32/EBX   0xc/disp8       .                 # copy *(EBP+12) to EBX
35     # if EAX == EBX success
36     39/compare                      3/mod/direct    0/rm32/EAX    .           .             .           3/r32/EBX   .               .                 # compare EAX and EBX
37     75/jump-if-unequal  $check-ints-equal:else/disp8
38     # . _write(2/stderr, '.')
39     # . . push args
40     68/push  "."/imm32
41     68/push  2/imm32/stderr
42     # . . call
43     e8/call  _write/disp32
44     # . . discard args
45     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
46     # . return
47     eb/jump  $check-ints-equal:end/disp8
48     # otherwise print error message
49 $check-ints-equal:else:
50     # . _write(2/stderr, msg)
51     # . . push args
52     8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           1/r32/ECX   0x10/disp8      .                 # copy *(EBP+16) to ECX
53     51/push-ECX
54     68/push  2/imm32/stderr
55     # . . call
56     e8/call  _write/disp32
57     # . . discard args
58     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
59     # . _write(2/stderr, Newline)
60     # . . push args
61     68/push  Newline/imm32
62     68/push  2/imm32/stderr
63     # . . call
64     e8/call  _write/disp32
65     # . . discard args
66     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
67     # increment Num-test-failures
68     ff          0/subop/increment   0/mod/indirect  5/rm32/.disp32            .             .           .           Num-test-failures/disp32          # increment *Num-test-failures
69 $check-ints-equal:end:
70     # . restore registers
71     5b/pop-to-EBX
72     59/pop-to-ECX
73     58/pop-to-EAX
74     # . epilog
75     89/copy                         3/mod/direct    4/rm32/ESP    .           .             .           5/r32/EBP   .               .                 # copy EBP to ESP
76     5d/pop-to-EBP
77     c3/return
78 
79 == data
80 
81 Newline:
82     # size
83     01 00 00 00
84     # data
85     0a/newline
86 
87 Num-test-failures:
88     00 00 00 00
89 
90 # . . vim:nowrap:textwidth=0