294 lines
13 KiB
Plaintext
294 lines
13 KiB
Plaintext
# read-byte-buffered: one higher-level abstraction atop 'read'.
|
|
#
|
|
# There are many situations where 'read' is a lot to manage, and we need
|
|
# to abstract some details away. One of them is when we want to read a file
|
|
# character by character. In this situation we follow C's FILE data structure,
|
|
# which manages the underlying file descriptor together with the buffer it
|
|
# reads into. We call our version 'buffered-file'. Should be useful with other
|
|
# primitives as well, in later layers.
|
|
|
|
== data
|
|
|
|
# The buffered file for standard input. Also illustrates the layout for
|
|
# buffered-file.
|
|
Stdin:
|
|
# file descriptor or (address stream)
|
|
0/imm32 # standard input
|
|
# current write index
|
|
0/imm32
|
|
# current read index
|
|
0/imm32
|
|
# length
|
|
8/imm32
|
|
# data
|
|
00 00 00 00 00 00 00 00 # 8 bytes
|
|
|
|
# TODO: 8 bytes is too small. We'll need to grow the buffer for efficiency. But
|
|
# I don't want to type in 1024 bytes here.
|
|
|
|
== code
|
|
# instruction effective address register displacement immediate
|
|
# . op subop mod rm32 base index scale r32
|
|
# . 1-3 bytes 3 bits 2 bits 3 bits 3 bits 3 bits 2 bits 2 bits 0/1/2/4 bytes 0/1/2/4 bytes
|
|
|
|
# return next byte value in EAX, with top 3 bytes cleared.
|
|
# On reaching end of file, return 0xffffffff (Eof).
|
|
read-byte-buffered: # f : (address buffered-file) -> byte-or-Eof/EAX
|
|
# . prolog
|
|
55/push-EBP
|
|
89/copy 3/mod/direct 5/rm32/EBP . . . 4/r32/ESP . . # copy ESP to EBP
|
|
# . save registers
|
|
51/push-ECX
|
|
56/push-ESI
|
|
# ESI = f
|
|
8b/copy 1/mod/*+disp8 5/rm32/EBP . . . 6/r32/ESI 8/disp8 . # copy *(EBP+8) to ESI
|
|
# ECX = f->read
|
|
8b/copy 1/mod/*+disp8 6/rm32/ESI . . . 1/r32/ECX 8/disp8 . # copy *(ESI+8) to ECX
|
|
# if (f->read >= f->write) populate stream from file
|
|
3b/compare 1/mod/*+disp8 6/rm32/ESI . . . 1/r32/ECX 4/disp8 . # compare ECX with *(ESI+4)
|
|
7c/jump-if-lesser $read-byte-buffered:from-stream/disp8
|
|
# . clear-stream(stream = f+4)
|
|
# . . push args
|
|
8d/copy-address 1/mod/*+disp8 6/rm32/ESI . . . 0/r32/EAX 4/disp8 . # copy ESI+4 to EAX
|
|
50/push-EAX
|
|
# . . call
|
|
e8/call clear-stream/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# . f->read must now be 0; update its cache at ECX
|
|
31/xor 3/mod/direct 1/rm32/ECX . . . 1/r32/ECX . . # clear ECX
|
|
# . EAX = read(f->fd, stream = f+4)
|
|
# . . push args
|
|
50/push-EAX
|
|
ff 6/subop/push 0/mod/indirect 6/rm32/ESI . . . . . . # push *ESI
|
|
# . . call
|
|
e8/call read/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
|
|
# if (EAX == 0) return 0xffffffff
|
|
3d/compare-EAX-and 0/imm32
|
|
75/jump-if-not-equal $read-byte-buffered:from-stream/disp8
|
|
b8/copy-to-EAX 0xffffffff/imm32/Eof
|
|
eb/jump $read-byte-buffered:end/disp8
|
|
$read-byte-buffered:from-stream:
|
|
# read byte from stream
|
|
# AL = f->data[f->read]
|
|
31/xor 3/mod/direct 0/rm32/EAX . . . 0/r32/EAX . . # clear EAX
|
|
8a/copy-byte 1/mod/*+disp8 4/rm32/sib 6/base/ESI 1/index/ECX . 0/r32/AL 0x10/disp8 . # copy byte at *(ESI+ECX+16) to AL
|
|
# ++f->read
|
|
ff 0/subop/increment 1/mod/*+disp8 6/rm32/ESI . . . . 8/disp8 . # increment *(ESI+8)
|
|
$read-byte-buffered:end:
|
|
# . restore registers
|
|
5e/pop-to-ESI
|
|
59/pop-to-ECX
|
|
# . epilog
|
|
89/copy 3/mod/direct 4/rm32/ESP . . . 5/r32/EBP . . # copy EBP to ESP
|
|
5d/pop-to-EBP
|
|
c3/return
|
|
|
|
# - tests
|
|
|
|
test-read-byte-buffered-single:
|
|
# - check that read-byte-buffered returns first byte of 'file'
|
|
# setup
|
|
# . clear-stream(_test-stream)
|
|
# . . push args
|
|
68/push _test-stream/imm32
|
|
# . . call
|
|
e8/call clear-stream/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# . clear-stream(_test-buffered-file+4)
|
|
# . . push args
|
|
b8/copy-to-EAX _test-buffered-file/imm32
|
|
05/add-to-EAX 4/imm32
|
|
50/push-EAX
|
|
# . . call
|
|
e8/call clear-stream/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# . write(_test-stream, "Ab")
|
|
# . . push args
|
|
68/push "Ab"/imm32
|
|
68/push _test-stream/imm32
|
|
# . . call
|
|
e8/call write/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
|
|
# read-byte-buffered(_test-buffered-file)
|
|
# . . push args
|
|
68/push _test-buffered-file/imm32
|
|
# . . call
|
|
e8/call read-byte-buffered/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# check-ints-equal(EAX, 'A', msg)
|
|
# . . push args
|
|
68/push "F - test-read-byte-buffered-single"/imm32
|
|
68/push 0x41/imm32
|
|
50/push-EAX
|
|
# . . call
|
|
e8/call check-ints-equal/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 0xc/imm32 # add to ESP
|
|
# . end
|
|
c3/return
|
|
|
|
test-read-byte-buffered-multiple:
|
|
# - call read-byte-buffered twice, check that second call returns second byte
|
|
# setup
|
|
# . clear-stream(_test-stream)
|
|
# . . push args
|
|
68/push _test-stream/imm32
|
|
# . . call
|
|
e8/call clear-stream/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# . clear-stream(_test-buffered-file+4)
|
|
# . . push args
|
|
b8/copy-to-EAX _test-buffered-file/imm32
|
|
05/add-to-EAX 4/imm32
|
|
50/push-EAX
|
|
# . . call
|
|
e8/call clear-stream/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# . write(_test-stream, "Ab")
|
|
# . . push args
|
|
68/push "Ab"/imm32
|
|
68/push _test-stream/imm32
|
|
# . . call
|
|
e8/call write/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
|
|
# read-byte-buffered(_test-buffered-file)
|
|
# . . push args
|
|
68/push _test-buffered-file/imm32
|
|
# . . call
|
|
e8/call read-byte-buffered/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# read-byte-buffered(_test-buffered-file)
|
|
# . . push args
|
|
68/push _test-buffered-file/imm32
|
|
# . . call
|
|
e8/call read-byte-buffered/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# check-ints-equal(EAX, 'b', msg)
|
|
# . . push args
|
|
68/push "F - test-read-byte-buffered-multiple"/imm32
|
|
68/push 0x62/imm32
|
|
50/push-EAX
|
|
# . . call
|
|
e8/call check-ints-equal/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 0xc/imm32 # add to ESP
|
|
# . end
|
|
c3/return
|
|
|
|
test-read-byte-buffered-end-of-file:
|
|
# - call read-byte-buffered on an empty 'file', check that it returns Eof
|
|
# setup
|
|
# . clear-stream(_test-stream)
|
|
# . . push args
|
|
68/push _test-stream/imm32
|
|
# . . call
|
|
e8/call clear-stream/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# . clear-stream(_test-buffered-file+4)
|
|
# . . push args
|
|
b8/copy-to-EAX _test-buffered-file/imm32
|
|
05/add-to-EAX 4/imm32
|
|
50/push-EAX
|
|
# . . call
|
|
e8/call clear-stream/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# read-byte-buffered(_test-buffered-file)
|
|
# . . push args
|
|
68/push _test-buffered-file/imm32
|
|
# . . call
|
|
e8/call read-byte-buffered/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# check-ints-equal(EAX, 0xffffffff, msg)
|
|
# . . push args
|
|
68/push "F - test-read-byte-buffered-end-of-file"/imm32
|
|
68/push 0xffffffff/imm32/Eof
|
|
50/push-EAX
|
|
# . . call
|
|
e8/call check-ints-equal/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 0xc/imm32 # add to ESP
|
|
# . end
|
|
c3/return
|
|
|
|
test-read-byte-buffered-refills-buffer:
|
|
# - consume buffered-file's buffer, check that next read-byte-buffered still works
|
|
# setup
|
|
# . clear-stream(_test-stream)
|
|
# . . push args
|
|
68/push _test-stream/imm32
|
|
# . . call
|
|
e8/call clear-stream/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# . clear-stream(_test-buffered-file+4)
|
|
# . . push args
|
|
b8/copy-to-EAX _test-buffered-file/imm32
|
|
05/add-to-EAX 4/imm32
|
|
50/push-EAX
|
|
# . . call
|
|
e8/call clear-stream/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# . write(_test-stream, "Abcdefgh")
|
|
# . . push args
|
|
68/push "Abcdefgh"/imm32
|
|
68/push _test-stream/imm32
|
|
# . . call
|
|
e8/call write/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
|
|
# pretend buffer is full
|
|
# . _test-buffered-file->read = 6 # >= _test-buffered-file->length
|
|
b8/copy-to-EAX _test-buffered-file/imm32
|
|
c7 0/subop/copy 1/mod/*+disp8 0/rm32/EAX . . . . 8/disp8 6/imm32 # copy to *(EAX+8)
|
|
# read-byte-buffered(_test-buffered-file)
|
|
# . . push args
|
|
68/push _test-buffered-file/imm32
|
|
# . . call
|
|
e8/call read-byte-buffered/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# check-ints-equal(EAX, 'A', msg)
|
|
# . . push args
|
|
68/push "F - test-read-byte-buffered-refills-buffer"/imm32
|
|
68/push 0x41/imm32
|
|
50/push-EAX
|
|
# . . call
|
|
e8/call check-ints-equal/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 0xc/imm32 # add to ESP
|
|
# . end
|
|
c3/return
|
|
|
|
== data
|
|
|
|
# a test buffered file for _test-stream
|
|
_test-buffered-file:
|
|
# file descriptor or (address stream)
|
|
_test-stream/imm32
|
|
# current write index
|
|
0/imm32
|
|
# current read index
|
|
0/imm32
|
|
# length
|
|
6/imm32
|
|
# data
|
|
00 00 00 00 00 00 # 6 bytes
|
|
|
|
# . . vim:nowrap:textwidth=0
|