162 lines
7.9 KiB
Plaintext
162 lines
7.9 KiB
Plaintext
== code
|
|
# instruction effective address register displacement immediate
|
|
# . op subop mod rm32 base index scale r32
|
|
# . 1-3 bytes 3 bits 2 bits 3 bits 3 bits 3 bits 2 bits 2 bits 0/1/2/4 bytes 0/1/2/4 bytes
|
|
|
|
# read all bytes from 'f' and store them into 's'
|
|
# abort if 's' is too small
|
|
slurp: # f : (address buffered-file), s : (address stream byte) -> <void>
|
|
# pseudocode:
|
|
# while true
|
|
# if (s->write >= s->length) abort
|
|
# if (f->read >= f->write) populate stream from file
|
|
# if (f->write == 0) break
|
|
# AL = f->data[f->read]
|
|
# s->data[s->write] = AL
|
|
# ++f->read
|
|
# ++s->write
|
|
# . prolog
|
|
55/push-EBP
|
|
89/copy 3/mod/direct 5/rm32/EBP . . . 4/r32/ESP . . # copy ESP to EBP
|
|
# . save registers
|
|
50/push-EAX
|
|
51/push-ECX
|
|
52/push-EDX
|
|
56/push-ESI
|
|
57/push-EDI
|
|
# ESI = f
|
|
8b/copy 1/mod/*+disp8 5/rm32/EBP . . . 6/r32/ESI 8/disp8 . # copy *(EBP+8) to ESI
|
|
# ECX = f->read
|
|
8b/copy 1/mod/*+disp8 6/rm32/ESI . . . 1/r32/ECX 8/disp8 . # copy *(ESI+8) to ECX
|
|
# EDI = s
|
|
8b/copy 1/mod/*+disp8 5/rm32/EBP . . . 7/r32/EDI 0xc/disp8 . # copy *(EBP+12) to EDI
|
|
# EDX = s->write
|
|
8b/copy 0/mod/indirect 7/rm32/EDI . . . 2/r32/EDX . . # copy *EDI to EDX
|
|
$slurp:loop:
|
|
# if (s->write >= s->length) abort
|
|
3b/compare 1/mod/*+disp8 7/rm32/EDI . . . 2/r32/EDX 8/disp8 . # compare EDX with *(EDI+8)
|
|
7d/jump-if-greater-or-equal $slurp:abort/disp8
|
|
# if (f->read >= f->write) populate stream from file
|
|
3b/compare 1/mod/*+disp8 6/rm32/ESI . . . 1/r32/ECX 4/disp8 . # compare ECX with *(ESI+4)
|
|
7c/jump-if-lesser $slurp:from-stream/disp8
|
|
# . clear-stream(stream = f+4)
|
|
# . . push args
|
|
8d/copy-address 1/mod/*+disp8 6/rm32/ESI . . . 0/r32/EAX 4/disp8 . # copy ESI+4 to EAX
|
|
50/push-EAX
|
|
# . . call
|
|
e8/call clear-stream/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# . f->read must now be 0; update its cache at ECX
|
|
31/xor 3/mod/direct 1/rm32/ECX . . . 1/r32/ECX . . # clear ECX
|
|
# . EAX = read(f->fd, stream = f+4)
|
|
# . . push args
|
|
50/push-EAX
|
|
ff 6/subop/push 0/mod/indirect 6/rm32/ESI . . . . . . # push *ESI
|
|
# . . call
|
|
e8/call read/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
|
|
# if (f->write == 0) break
|
|
# since f->read was initially 0, EAX is the same as f->write
|
|
# . if (EAX == 0) return true
|
|
3d/compare-EAX-and 0/imm32
|
|
74/jump-if-equal $slurp:end/disp8
|
|
$slurp:from-stream:
|
|
# AL = f->data[f->read]
|
|
31/xor 3/mod/direct 0/rm32/EAX . . . 0/r32/EAX . . # clear EAX
|
|
8a/copy-byte 1/mod/*+disp8 4/rm32/sib 6/base/ESI 1/index/ECX . 0/r32/AL 0x10/disp8 . # copy byte at *(ESI+ECX+16) to AL
|
|
# s->data[s->write] = AL
|
|
88/copy-byte 1/mod/*+disp8 4/rm32/sib 7/base/EDI 2/index/EDX . 0/r32/AL 0xc/disp8 . # copy AL to *(EDI+EDX+12)
|
|
# ++f->read
|
|
41/increment-ECX
|
|
# ++s->write
|
|
42/increment-EDX
|
|
eb/jump $slurp:loop/disp8
|
|
$slurp:end:
|
|
# save f->read
|
|
89/copy 1/mod/*+disp8 6/rm32/ESI . . . 1/r32/ECX 8/disp8 . # copy ECX to *(ESI+8)
|
|
# save s->write
|
|
89/copy 0/mod/indirect 7/rm32/EDI . . . 2/r32/EDX . . # copy EDX to *EDI
|
|
# . restore registers
|
|
5f/pop-to-EDI
|
|
5e/pop-to-ESI
|
|
5a/pop-to-EDX
|
|
59/pop-to-ECX
|
|
58/pop-to-EAX
|
|
# . epilog
|
|
89/copy 3/mod/direct 4/rm32/ESP . . . 5/r32/EBP . . # copy EBP to ESP
|
|
5d/pop-to-EBP
|
|
c3/return
|
|
|
|
$slurp:abort:
|
|
# . _write(2/stderr, error)
|
|
# . . push args
|
|
68/push "slurp: destination too small\n"/imm32
|
|
68/push 2/imm32/stderr
|
|
# . . call
|
|
e8/call _write/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
|
|
# . syscall(exit, 1)
|
|
bb/copy-to-EBX 1/imm32
|
|
b8/copy-to-EAX 1/imm32/exit
|
|
cd/syscall 0x80/imm8
|
|
# never gets here
|
|
|
|
test-slurp:
|
|
# setup
|
|
# . clear-stream(_test-stream)
|
|
# . . push args
|
|
68/push _test-stream/imm32
|
|
# . . call
|
|
e8/call clear-stream/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# . clear-stream(_test-buffered-file+4)
|
|
# . . push args
|
|
b8/copy-to-EAX _test-buffered-file/imm32
|
|
05/add-to-EAX 4/imm32
|
|
50/push-EAX
|
|
# . . call
|
|
e8/call clear-stream/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# . clear-stream(_test-tmp-stream)
|
|
# . . push args
|
|
68/push _test-tmp-stream/imm32
|
|
# . . call
|
|
e8/call clear-stream/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
|
|
# write(_test-stream, "ab\ncd")
|
|
# . . push args
|
|
68/push "ab\ncd"/imm32
|
|
68/push _test-stream/imm32
|
|
# . . call
|
|
e8/call write/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
|
|
# read a line from _test-stream (buffered by _test-buffered-file) into _test-tmp-stream
|
|
# . EAX = slurp(_test-buffered-file, _test-tmp-stream)
|
|
# . . push args
|
|
68/push _test-tmp-stream/imm32
|
|
68/push _test-buffered-file/imm32
|
|
# . . call
|
|
e8/call slurp/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
|
|
# check-stream-equal(_test-tmp-stream, "ab\ncd", msg)
|
|
# . . push args
|
|
68/push "F - test-slurp"/imm32
|
|
68/push "ab\ncd"/imm32
|
|
68/push _test-tmp-stream/imm32
|
|
# . . call
|
|
e8/call check-stream-equal/disp32
|
|
# . . discard args
|
|
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 0xc/imm32 # add to ESP
|
|
# end
|
|
c3/return
|
|
|
|
# . . vim:nowrap:textwidth=0
|