{
  description = "My NixOS configuration";

  inputs = {
    nixpkgs.url = "nixpkgs/nixos-unstable";

    home-manager.url = "github:nix-community/home-manager";
    nur.url = "github:nix-community/NUR";
    emacs-overlay.url = "github:nix-community/emacs-overlay";
    #nix-doom-emacs.url = "github:nix-community/nix-doom-emacs";
    nix-doom-emacs.url =
      "git+https://codeberg.org/jezcope/nix-doom-emacs?ref=fix/evil-collection";
    nix-std.url = "github:chessai/nix-std";

    home-manager.inputs.nixpkgs.follows = "nixpkgs";
    emacs-overlay.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = { self, nixpkgs, home-manager, nur, emacs-overlay, nix-std
    , nix-doom-emacs, ... }@inputs:
    let
      inherit (nixpkgs.lib) genAttrs nixosSystem;

      system = "x86_64-linux";
      hosts = [ "arianrhod" "gwydion" ];
      overlay = import ./overlay.nix;
      std = nix-std.lib;
    in {
      inherit overlay;

      nixosConfigurations = genAttrs hosts (hostName:
        nixosSystem {
          inherit system;
          modules = [
            ./profiles
            ./configuration.nix
            (./hosts + "/${hostName}")
            (./secrets + "/${hostName}.nix")

            {
              nixpkgs.overlays = [ overlay nur.overlay emacs-overlay.overlay ];
            }

            home-manager.nixosModules.home-manager
            {
              home-manager = {
                useGlobalPkgs = true;
                useUserPackages = true;
                users.jez = { imports = [ nix-doom-emacs.hmModule ./home ]; };
                extraSpecialArgs = { inherit std; };
              };
            }
          ];
          specialArgs = { inherit inputs hostName; };
        });

    };
}