{
  description = "My NixOS configuration";

  inputs = {
    nixpkgs.url = "nixpkgs/nixos-unstable";

    home-manager.url = "github:nix-community/home-manager";
    nur.url = "github:nix-community/NUR";
    emacs-overlay.url = "github:nix-community/emacs-overlay";

    home-manager.inputs.nixpkgs.follows = "nixpkgs";
    nur.inputs.nixpkgs.follows = "nixpkgs";
    emacs-overlay.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = { self, nixpkgs, home-manager, nur, emacs-overlay, ... }@inputs:
    let
      inherit (nixpkgs.lib) genAttrs nixosSystem;

      system = "x86_64-linux";
      hosts = [ "arianrhod" "gwydion" ];
      overlay = import ./overlay.nix;
    in {
      inherit overlay;

      nixosConfigurations = genAttrs hosts (hostName:
        nixosSystem {
          inherit system;
          modules = [
            ./profiles
            ./configuration.nix
            (./hosts + "/${hostName}")
            (./secrets + "/${hostName}.nix")

            {
              nixpkgs.overlays = [ overlay nur.overlay emacs-overlay.overlay ];
            }

            home-manager.nixosModules.home-manager
            {
              home-manager = {
                useGlobalPkgs = true;
                useUserPackages = true;
                users.jez = import ./home;
              };
            }
          ];
          specialArgs = { inherit inputs hostName; };
        });

    };
}