new powerful synth - amateur

cabbages/amateur.csd

@@ -0,0 +1,137 @@
+<Cabbage> bounds(0, 0, 0, 0)
+form caption("Amateur") size(400, 300), colour(0, 51, 153),pluginid("amat")
+keyboard bounds(6, 170, 381, 95)
+combobox bounds(6, 34, 80, 20) channel("osc1") text("piano", "el piano", "e-bass", "e-organ", "distorted", "guitar", "organ", "oboe")
+combobox bounds(138, 34, 80, 20) text("piano", "el piano", "e-bass", "e-organ", "distorted", "guitar", "organ", "oboe") channel("osc2") value(2)
+rslider bounds(90, 30, 45, 37) range(0, 1, 0.5, 1, 0.001) channel("oscmix")
+
+label bounds(74, 12, 80, 16) text("OSC")
+label bounds(72, 74, 80, 16) text("ENV")
+rslider bounds(36, 96, 55, 43) range(0.01, 1, 0.01, 1, 0.001) channel("attack")
+rslider bounds(130, 96, 53, 45) range(0.01, 1, 0.5, 1, 0.001) channel("decay")
+checkbox bounds(98, 100, 27, 30) channel("hold") value(1)
+label bounds(264, 8, 80, 16) text("FILTER")
+rslider bounds(242, 24, 58, 47) range(0, 1, 1, 1, 0.001) channel("filter")
+rslider bounds(308, 26, 40, 34) range(0, 1, 0, 1, 0.001) channel("resonance")
+label bounds(248, 74, 80, 16) text("FX")
+rslider bounds(248, 96, 48, 41) range(0, 1, 0, 1, 0.001) channel("reverb")
+label bounds(246, 142, 49, 16) text("reverb")
+rslider bounds(304, 96, 46, 42) range(0, 1, 0, 1, 0.001) channel("chorus")
+label bounds(302, 142, 57, 16) text("chorus")
+vslider bounds(188, 72, 50, 87) range(0, 1, 0.5, 1, 0.001) channel("vol")
+</Cabbage>
+<CsoundSynthesizer>
+<CsOptions>
+-n -d -+rtmidi=NULL -M0 -m0d --midi-key-cps=4 --midi-velocity-amp=5
+</CsOptions>
+<CsInstruments>
+; Initialize the global variables. 
+ksmps = 32
+nchnls = 2
+0dbfs = 1
+
+giWaves[] init 9
+
+giWaves[1] ftgen 0, 0, 0, 1, "awkf/AKWF_piano_0001.wav", 0, 0, 0
+giWaves[2] ftgen 0, 0, 0, 1, "awkf/AKWF_epiano_0014.wav", 0, 0, 0
+giWaves[3] ftgen 0, 0, 0, 1, "awkf/AKWF_ebass_0042.wav", 0, 0, 0
+giWaves[4] ftgen 0, 0, 0, 1, "awkf/AKWF_eorgan_0033.wav", 0, 0, 0
+giWaves[5] ftgen 0, 0, 0, 1, "awkf/AKWF_eguitar_0011.wav", 0, 0, 0
+giWaves[6] ftgen 0, 0, 0, 1, "awkf/AKWF_eguitar_0003.wav", 0, 0, 0
+giWaves[7] ftgen 0, 0, 0, 1, "awkf/AKWF_eorgan_0114.wav", 0, 0, 0
+giWaves[8] ftgen 0, 0, 0, 1, "awkf/AKWF_oboe_0013.wav", 0, 0, 0
+
+gaOut init 0
+
+;instrument will be triggered by keyboard widget
+instr 1
+    kbnd pchbend 0, 100
+    kcps = p4 + kbnd
+    
+    
+    iosc1 chnget "osc1"
+    aOutA poscil3 0.6, kcps, giWaves[iosc1]
+    
+    iosc2 chnget "osc2"
+    aOutB poscil3 0.6, kcps, giWaves[iosc2]
+
+    koscmix chnget "oscmix"
+    aOut ntrpol aOutA, aOutB, koscmix
+    
+    iattack chnget "attack"
+    idecay chnget "decay"
+    isustain chnget "hold"
+    
+    
+    
+    if isustain == 1 then
+        kEnv madsr iattack, 0.0001, 1, idecay+iattack
+    else
+        kEnv linsegr 0, iattack, 1, idecay, 0, iattack+idecay, 0
+    endif
+    
+    ; printk 0.1, kEnv
+            
+    gaOut += aOut*kEnv
+endin
+
+instr 2
+    aOut = gaOut
+    
+    kfilter chnget "filter"
+    kresonance chnget "resonance"
+    
+    ; filter
+    aOut moogladder aOut, kfilter*22000, kresonance
+    
+    aL = aOut
+    aR = aOut
+    
+    
+    kchorus chnget "chorus"
+    kchorus = kchorus / 2
+    
+    ; chorus
+    amod1 = randi:a(3,.75)+oscili(2,.35)+31
+    amod2 = randi:a(2,.65)+oscili(3,.55)+29
+    a1 = vdelay(aL*.5,amod1,35)
+    a2 = vdelay(aR*.5,amod2,35)
+
+    aLchorus = aL + a1
+    aRchorus = aR + a2 
+    
+    aL = aL + (aLchorus * kchorus)
+    aR = aR + (aRchorus * kchorus)
+    
+    ; reverb
+    kreverb chnget "reverb"
+    kreverb = kreverb / 3 
+    
+    aLreverb, aRreverb reverbsc aL, aR, 0.8, 12000
+    
+    aL = aL + (aLreverb * kreverb)
+    aR = aR + (aRreverb * kreverb)
+    
+    ; volume
+    
+    kVol chnget "vol"
+    
+    aL clip aL*kVol, 0, 0.9
+    aR clip aR*kVol, 0, 0.9
+    
+    outs aL, aR
+    gaOut = 0
+endin
+
+schedule 2, 0, -1
+
+
+
+
+
+</CsInstruments>
+<CsScore>
+;causes Csound to run for about 7000 years...
+f0 z
+</CsScore>
+</CsoundSynthesizer>

cabbages/awkf/AdventureKidWaveforms.txt

@@ -0,0 +1,47 @@
+
+Adventure Kid
+
+http://www.adventurekid.se
+http://www.adventurekid.se/AKRT
+
+---------------------------------------------------
+
+Adventure Kid Waveforms (AKWF)
+
+AKWF is a collection of one cycle waveforms sampled
+from various sources intended for use as oscillator
+shapes in samplers and synthesizers.
+
+Length = 600 samples
+Pitch = D1+2
+
+You find them on-line at:
+http://www.adventurekid.se/AKRT
+
+---------------------------------------------------
+
+Adventure Kid Research & Technology (AKRT)
+
+While making music I have always try what happens
+if I miss use something and try to find things
+through experimenting - I love both old technology
+and new. Through the years I have sampled a lot of
+stuff, programmed my own synthesizers and effects 
+and tried a lot of techniques. Adventure Kid
+Research & Technology is my way of both collecting
+and sharing what I make and find.
+
+---------------------------------------------------
+
+Adventure Kid
+
+Adventure Kid is the stage name of Kristoffer
+Ekstrand (born July 22, 1982). Kristoffer who is
+based in Sweden uses obsolete personal computers,
+hand held gaming consoles and video game consoles in
+conjunction with modern synthesizers and sequencers
+to create music and art.
+
+---------------------------------------------------
+
+http://www.adventurekid.se/AKRT