366 lines
8.2 KiB
Plaintext
366 lines
8.2 KiB
Plaintext
|
|
void() T_MissileTouch;
|
|
void() info_player_start;
|
|
void(entity targ, entity attacker) ClientObituary;
|
|
|
|
void() monster_death_use;
|
|
|
|
//============================================================================
|
|
|
|
/*
|
|
============
|
|
CanDamage
|
|
|
|
Returns true if the inflictor can directly damage the target. Used for
|
|
explosions and melee attacks.
|
|
============
|
|
*/
|
|
float(entity targ, entity inflictor) CanDamage =
|
|
{
|
|
// bmodels need special checking because their origin is 0,0,0
|
|
if (targ.movetype == MOVETYPE_PUSH)
|
|
{
|
|
traceline(inflictor.origin, 0.5 * (targ.absmin + targ.absmax), TRUE, self);
|
|
if (trace_fraction == 1)
|
|
return TRUE;
|
|
if (trace_ent == targ)
|
|
return TRUE;
|
|
return FALSE;
|
|
}
|
|
|
|
traceline(inflictor.origin, targ.origin, TRUE, self);
|
|
if (trace_fraction == 1)
|
|
return TRUE;
|
|
traceline(inflictor.origin, targ.origin + '15 15 0', TRUE, self);
|
|
if (trace_fraction == 1)
|
|
return TRUE;
|
|
traceline(inflictor.origin, targ.origin + '-15 -15 0', TRUE, self);
|
|
if (trace_fraction == 1)
|
|
return TRUE;
|
|
traceline(inflictor.origin, targ.origin + '-15 15 0', TRUE, self);
|
|
if (trace_fraction == 1)
|
|
return TRUE;
|
|
traceline(inflictor.origin, targ.origin + '15 -15 0', TRUE, self);
|
|
if (trace_fraction == 1)
|
|
return TRUE;
|
|
|
|
return FALSE;
|
|
};
|
|
|
|
|
|
/*
|
|
============
|
|
Killed
|
|
============
|
|
*/
|
|
void(entity targ, entity attacker) Killed =
|
|
{
|
|
local entity oself;
|
|
|
|
oself = self;
|
|
self = targ;
|
|
|
|
if (self.health < -99)
|
|
self.health = -99; // don't let sbar look bad if a player
|
|
|
|
// so we can find out who shot the box that kilt self
|
|
if (self.classname == "misc_explobox" || self.classname == "misc_explobox2")
|
|
self.enemy = attacker;
|
|
|
|
if (self.movetype == MOVETYPE_PUSH || self.movetype == MOVETYPE_NONE)
|
|
{ // doors, triggers, etc
|
|
self.th_die ();
|
|
self = oself;
|
|
return;
|
|
}
|
|
|
|
self.enemy = attacker;
|
|
|
|
// bump the monster counter
|
|
if (self.flags & FL_MONSTER)
|
|
{
|
|
killed_monsters = killed_monsters + 1;
|
|
local entity pl;
|
|
|
|
// [slipyx] add to player frag count. regain monster frags too
|
|
if (attacker.classname == "player")
|
|
pl = attacker;
|
|
// for explo_box
|
|
else if (!(attacker.flags & FL_MONSTER) &&
|
|
attacker.enemy.classname == "player")
|
|
pl = attacker.enemy;
|
|
|
|
if (pl) {
|
|
pl.frags += (1);
|
|
|
|
// bonus shambler brag message :)
|
|
if (self.classname == "monster_shambler") {
|
|
bprint (pl.netname); bprint (" killed a shambler!\n");
|
|
}
|
|
|
|
// was a revenge kill, gain monster's kills
|
|
if (self.frags > 0) {
|
|
pl.frags += self.frags;
|
|
bprint (pl.netname);
|
|
if (pl.netname != self.netname) {
|
|
bprint (" avenged "); bprint (self.netname);
|
|
} else bprint (" got revenge");
|
|
bprint ("!\n");
|
|
}
|
|
}
|
|
|
|
WriteByte (MSG_ALL, SVC_KILLEDMONSTER);
|
|
}
|
|
|
|
// [slipyx] add to monster's frag count.
|
|
if ((attacker.flags & FL_MONSTER)) {
|
|
// absorb monsters frags and recent kill name too
|
|
if (self.flags & FL_MONSTER) {
|
|
if (self.frags > 0) {
|
|
attacker.frags += self.frags;
|
|
attacker.netname = self.netname;
|
|
}
|
|
}
|
|
|
|
// only add player kills
|
|
if (self.classname == "player") {
|
|
attacker.frags += 1;
|
|
// keep track of recent player killed
|
|
attacker.netname = self.netname;
|
|
}
|
|
|
|
// some bonus visual effects
|
|
if (attacker.frags > 0) {
|
|
attacker.effects = (EF_DIMLIGHT | EF_BLUE);
|
|
}
|
|
if (attacker.frags > 1) {
|
|
attacker.effects = (EF_DIMLIGHT | EF_RED);
|
|
}
|
|
if (attacker.frags > 2) {
|
|
attacker.effects = (EF_DIMLIGHT | EF_RED | EF_BLUE);
|
|
}
|
|
}
|
|
|
|
ClientObituary(self, attacker);
|
|
|
|
self.takedamage = DAMAGE_NO;
|
|
self.touch = SUB_Null;
|
|
self.effects = 0;
|
|
|
|
monster_death_use();
|
|
self.th_die ();
|
|
|
|
self = oself;
|
|
};
|
|
|
|
/*
|
|
============
|
|
T_Damage
|
|
|
|
The damage is coming from inflictor, but get mad at attacker
|
|
This should be the only function that ever reduces health.
|
|
============
|
|
*/
|
|
void(entity targ, entity inflictor, entity attacker, float damage) T_Damage=
|
|
{
|
|
local vector dir;
|
|
local entity oldself;
|
|
local float save;
|
|
local float take;
|
|
// [slipyx] is both targ and attacker a client? and the same client?
|
|
local float bothcl, samecl;
|
|
|
|
if (!targ.takedamage)
|
|
return;
|
|
|
|
// [slipyx] detect if both targ and attacker are clients and if the same
|
|
bothcl = ((targ.flags & FL_CLIENT) && (attacker.flags & FL_CLIENT));
|
|
samecl = FALSE;
|
|
if ( bothcl ) samecl = (targ == attacker);
|
|
|
|
// used by buttons and triggers to set activator for target firing
|
|
damage_attacker = attacker;
|
|
|
|
// check for quad damage powerup on the attacker
|
|
if (attacker.super_damage_finished > time)
|
|
damage = damage * 4;
|
|
|
|
// save damage based on the target's armor level
|
|
|
|
// [slipyx] coop client teamplay armor damage avoidance
|
|
if ( coop && (teamplay == 1) && bothcl )
|
|
save = 0;
|
|
else
|
|
save = ceil(targ.armortype*damage);
|
|
|
|
if (save >= targ.armorvalue)
|
|
{
|
|
save = targ.armorvalue;
|
|
targ.armortype = 0; // lost all armor
|
|
targ.items = targ.items - (targ.items & (IT_ARMOR1 | IT_ARMOR2 | IT_ARMOR3));
|
|
}
|
|
|
|
targ.armorvalue = targ.armorvalue - save;
|
|
take = ceil(damage-save);
|
|
|
|
// add to the damage total for clients, which will be sent as a single
|
|
// message at the end of the frame
|
|
// FIXME: remove after combining shotgun blasts?
|
|
if (targ.flags & FL_CLIENT)
|
|
{
|
|
targ.dmg_take = targ.dmg_take + take;
|
|
targ.dmg_save = targ.dmg_save + save;
|
|
targ.dmg_inflictor = inflictor;
|
|
}
|
|
damage_inflictor = inflictor;
|
|
|
|
// figure momentum add
|
|
if ( (inflictor != world) && (targ.movetype == MOVETYPE_WALK) )
|
|
{
|
|
// [slipyx] no momentum against coop client teammates
|
|
if ( !(coop && (teamplay == 1) && bothcl && !samecl) ) {
|
|
|
|
dir = targ.origin - (inflictor.absmin + inflictor.absmax) * 0.5;
|
|
dir = normalize(dir);
|
|
targ.velocity = targ.velocity + dir*damage*8;
|
|
}
|
|
}
|
|
|
|
// check for godmode or invincibility
|
|
if (targ.flags & FL_GODMODE)
|
|
return;
|
|
if (targ.invincible_finished >= time)
|
|
{
|
|
if (self.invincible_sound < time)
|
|
{
|
|
sound (targ, CHAN_ITEM, "items/protect3.wav", 1, ATTN_NORM);
|
|
self.invincible_sound = time + 2;
|
|
}
|
|
return;
|
|
}
|
|
|
|
// [slipyx] coop client teamplay damage avoidance
|
|
if ( coop && (teamplay == 1) && bothcl ) return;
|
|
// teamplay damage avoidance
|
|
if ( (teamplay == 1) && (targ.team > 0)&&(targ.team == attacker.team) ) return;
|
|
|
|
// do the damage
|
|
targ.health = targ.health - take;
|
|
|
|
if (targ.health <= 0)
|
|
{
|
|
Killed (targ, attacker);
|
|
return;
|
|
}
|
|
|
|
// react to the damage
|
|
oldself = self;
|
|
self = targ;
|
|
|
|
if ( (self.flags & FL_MONSTER) && attacker != world)
|
|
{
|
|
// get mad unless of the same class (except for soldiers)
|
|
if (self != attacker && attacker != self.enemy)
|
|
{
|
|
if ( (self.classname != attacker.classname)
|
|
|| (self.classname == "monster_army" ) )
|
|
{
|
|
if (self.enemy.classname == "player")
|
|
self.oldenemy = self.enemy;
|
|
self.enemy = attacker;
|
|
FoundTarget ();
|
|
}
|
|
}
|
|
}
|
|
|
|
if (self.th_pain)
|
|
{
|
|
self.th_pain (attacker, take);
|
|
// nightmare mode monsters don't go into pain frames often
|
|
if (skill == 3)
|
|
self.pain_finished = time + 5;
|
|
}
|
|
|
|
self = oldself;
|
|
};
|
|
|
|
/*
|
|
============
|
|
T_RadiusDamage
|
|
============
|
|
*/
|
|
void(entity inflictor, entity attacker, float damage, entity ignore) T_RadiusDamage =
|
|
{
|
|
local float points;
|
|
local entity head;
|
|
local vector org;
|
|
|
|
head = findradius(inflictor.origin, damage+40);
|
|
|
|
while (head)
|
|
{
|
|
if (head != ignore)
|
|
{
|
|
if (head.takedamage)
|
|
{
|
|
org = head.origin + (head.mins + head.maxs)*0.5;
|
|
points = 0.5*vlen (inflictor.origin - org);
|
|
if (points < 0)
|
|
points = 0;
|
|
points = damage - points;
|
|
if (head == attacker)
|
|
points = points * 0.5;
|
|
if (points > 0)
|
|
{
|
|
if (CanDamage (head, inflictor))
|
|
{ // shambler takes half damage from all explosions
|
|
if (head.classname == "monster_shambler")
|
|
T_Damage (head, inflictor, attacker, points*0.5);
|
|
else
|
|
T_Damage (head, inflictor, attacker, points);
|
|
}
|
|
}
|
|
}
|
|
}
|
|
head = head.chain;
|
|
}
|
|
};
|
|
|
|
/*
|
|
============
|
|
T_BeamDamage
|
|
============
|
|
*/
|
|
/*void(entity attacker, float damage) T_BeamDamage =
|
|
{
|
|
local float points;
|
|
local entity head;
|
|
|
|
head = findradius(attacker.origin, damage+40);
|
|
|
|
while (head)
|
|
{
|
|
if (head.takedamage)
|
|
{
|
|
points = 0.5*vlen (attacker.origin - head.origin);
|
|
if (points < 0)
|
|
points = 0;
|
|
points = damage - points;
|
|
if (head == attacker)
|
|
points = points * 0.5;
|
|
if (points > 0)
|
|
{
|
|
if (CanDamage (head, attacker))
|
|
{
|
|
if (head.classname == "monster_shambler")
|
|
T_Damage (head, attacker, attacker, points*0.5);
|
|
else
|
|
T_Damage (head, attacker, attacker, points);
|
|
}
|
|
}
|
|
}
|
|
head = head.chain;
|
|
}
|
|
};*/
|
|
|