Let's make a game!
	name:Tilde Clicker
	by:Orteil
	desc:This is a simple idle game to showcase some of the basic functionalities of Idle Game Maker.<//>Make tildes and shoot for the stars!
	created:25/7/2017
	updated:24/10/2017
	version:1

Settings
	background:stuff/meadow.jpg
	building cost increase:115%
	building cost refund:50%
	spritesheet:icons, 48 by 48, stuff/tildeIcons.png
	stylesheet:stuff/bigBlue.css

Layout
	use default
		
Buttons
	*tildeButton
		name:Make a tilde
		desc:Click this little tilde to get more tildes!
		on click:anim icon wobble
		on click:yield 1 tilde
		on click:if (have goldenTouch and chance(1%)) yield 1 goldenCarrot
		icon:stuff/tilde.png
		no text
		class:bigButton hasFlares
		icon class:shadowed
		tooltip origin:bottom
		tooltip class:red
		
Resources
	*tilde|tildes
		name:Tilde|Tildes
		desc:These are your tildes. You can use them to purchase things. Your goal is to have as many tildes as possible!
		icon:icons[0,0]
		class:noBackground
		show earned
		
	*goldenCarrot|goldenCarrots
		name:Golden carrot|Golden carrots
		desc:These shiny carrots are terribly rare, terribly precious and terribly delicious!
		icon:icons[0,1]
		class:noBackground
		hidden when 0
		
Shinies
	*luckyTilde
		on click:log Woop
		movement:onRight moveLeft fade bounce:0.05
		frequency:60
		frequency variation:30
		icon:stuff/luckyTilde.png
		class:bigButton
		on click:
			$boost=1
			if (have clover) $boost=4
			if (chance(25%))
				//get at least 7, or between 1 and 3 minutes of our tilde production
				$amount=max(7,random(tildes:ps*60*1,tildes:ps*60*3))*$boost
				toast The lucky tilde grants you<//><b>[$amount] tildes</b>.
				yield $amount tildes
			else
				$amount=1*$boost
				toast The lucky tilde grants you<//><b>[$amount] golden carrot[s?$amount]</b>!
				yield $amount goldenCarrot
			end
		end

Buildings
	*TEMPLATE
		on click:anim glow
		
	*cage|cages
		name:Tilde cage|Tilde cages
		desc:A tiny little cage.<//><b>Effect:</b><.>Produces 1 tilde every 10 seconds.
		icon:icons[3,0]
		cost:15 tildes
		on tick:yield 0.1 tilde
		unlocked
	
	*hutch|hutches
		name:Tilde hutch|Tilde hutches
		desc:A bit roomier than a cage, with enough space to hop around.<//><b>Effect:</b><.>Produces 1 tilde every 2 seconds.
		icon:icons[3,1]
		cost:100 tildes
		on tick:yield 0.5 tildes
		req:100 tildes:earned
	
	*coop|coops
		name:Tilde coop|Tilde coops
		desc:A much nicer tilde home where full tilde families can live.<//><b>Effect:</b><.>Produces 5 tildes per second.
		icon:icons[3,2]
		cost:600 tildes
		on tick:yield 5 tildes
		req:600 tildes:earned
	
	*pen|pens
		name:Tilde pen|Tilde pens
		desc:A lovely enclosure with plenty of green space.<//><b>Effect:</b><.>Produces 12 tildes per second.
		icon:icons[3,3]
		cost:4000 tildes
		on tick:yield 12 tildes
		req:4000 tildes:earned
	
	*meadow|meadows
		name:Tilde meadow|Tilde meadows
		desc:A wide open space full of shade and lush grass.<//><b>Effect:</b><.>Produces 90 tildes per second.
		icon:icons[3,4]
		cost:20000 tildes
		on tick:yield 90 tildes
		req:20000 tildes:earned
	
	*village|villages
		name:Tilde village|Tilde villages
		desc:Your tildes are building their own villages now!<//><b>Effect:</b><.>Produces 300 tildes per second.
		icon:icons[3,5]
		cost:200000 tildes, 1 goldenCarrot
		on tick:yield 300 tildes
		req:200000 tildes:earned and independenceDay
		
	*city|cities
		name:Tilde city|Tilde cities
		desc:A bustling little city, populated with busy tildes.<//><b>Effect:</b><.>Produces 1000 tildes per second.
		icon:icons[3,6]
		cost:3000000 tildes, 4 goldenCarrots
		on tick:yield 1000 tildes
		req:3000000 tildes:earned and independenceDay
		
	*citadel|citadels
		name:Moon citadel|Moon citadels
		desc:An ornate palace standing on the moon, ruled by tilde kings and queens and staffed with royal tilde guards.<//><b>Effect:</b><.>Produces 4000 tildes per second.
		icon:icons[3,7]
		cost:70000000 tildes, 16 goldenCarrots
		on tick:yield 4000 tildes
		on tick:if (have moonGardens) yield 0.01 goldenCarrot
		req:70000000 tildes:earned and independenceDay
		
	*fortress
		name:Freedom fortress
		text:Freedom fortress ([this]%)
		desc:A huge tilde castle. A monument to the adventurous spirit of tildekind, which will take time and effort to complete.<//><b>The fortress is [this]% complete.</b>
		icon:icons[3,8]
		cost:300000000 tildes, 100 goldenCarrots
		req:70000000 tildes:earned and independenceDay
		limit:100
		cost increase:105%
		
Upgrades
	*TEMPLATE
		on click:anim glow
	
	*parsley
		name:Parsley
		desc:A nice little supplement to your tildes' diet.<//><b>Effect:</b><.>+1 tilde/click
		icon:icons[1,1]
		cost:100 tildes
		passive:increase tilde yield of tildeButton by 1
		req:10 tildes:earned
		
	*spinach
		name:Spinach
		desc:Big tasty leaves, perfect for hungry tildes.<//><b>Effect:</b><.>+1 tilde/click
		icon:icons[1,2]
		cost:200 tildes
		passive:increase tilde yield of tildeButton by 1
		req:50 tildes:earned
		
	*lettuce
		name:Lettuce
		desc:Frilly greens loved by all tildes.<//><b>Effect:</b><.>+1 tilde/click
		icon:icons[1,3]
		cost:400 tildes
		passive:increase tilde yield of tildeButton by 1
		req:200 tildes:earned
		
	*broccoli
		name:Broccoli
		desc:Crunchy greens that look like little trees.<//><b>Effect:</b><.>tildes/click x2<.>tilde production +5%
		icon:icons[1,4]
		cost:3000 tildes
		passive:multiply tilde yield of tildeButton by 2
		passive:multiply yield of tildes by 1.05
		req:1000 tildes:earned
		
	*apple
		name:Apple
		desc:Nice pieces of juicy red apples.<//><b>Effect:</b><.>tildes/click x1.5<.>tilde production +5%
		icon:icons[1,5]
		cost:10000 tildes
		passive:multiply tilde yield of tildeButton by 1.5
		passive:multiply yield of tildes by 1.05
		req:1000 tildes:earned
		
	*radish
		name:Radish
		desc:Purple, crunchy, and strangely spicy.<//><b>Effect:</b><.>tildes/click x1.5<.>tilde production +5%
		icon:icons[1,6]
		cost:50000 tildes
		passive:multiply tilde yield of tildeButton by 1.5
		passive:multiply yield of tildes by 1.05
		req:10000 tildes:earned
		
	*mint
		name:Mint
		desc:Tasty, and gives your tildes a lovely breath.<//><b>Effect:</b><.>tildes/click x1.5<.>tilde production +5%
		icon:icons[1,7]
		cost:100000 tildes
		passive:multiply tilde yield of tildeButton by 1.5
		passive:multiply yield of tildes by 1.05
		req:50000 tildes:earned
		
	*chard
		name:Chard
		desc:Broad leaves that make for a tasty salad.<//><b>Effect:</b><.>tildes/click x1.5<.>tilde production +5%
		icon:icons[1,8]
		cost:500000 tildes
		passive:multiply tilde yield of tildeButton by 1.5
		passive:multiply yield of tildes by 1.05
		req:100000 tildes:earned
		
	*cherry
		name:Cherry
		desc:Your tildes look like little vampires when they start munching on these!<//><b>Effect:</b><.>tildes/click x1.5<.>tilde production +5%
		icon:icons[1,9]
		cost:1000000 tildes
		passive:multiply tilde yield of tildeButton by 1.5
		passive:multiply yield of tildes by 1.05
		req:500000 tildes:earned
		
	*carrot
		name:Carrot
		desc:The quintessential tilde food! Crunchy, orange, and perfect.<//><b>Effect:</b><.>tildes/click x2<.>tilde production +10%
		icon:icons[1,0]
		cost:100000000 tildes
		passive:multiply tilde yield of tildeButton by 2
		passive:multiply yield of tildes by 1.1
		req:1000000 tildes:earned
	
	//building upgrades
	
	*buildingUpgrade1
		name:Sippy bottles
		desc:Your tildes can drink their fill!<//><b>Effect:</b><.>tilde cage production x2<.>tilde hutch production x2<.>tilde coop production x2
		icon:icons[2,0] icons[3,0]
		cost:1000 tildes
		passive:multiply yield of cage by 2
		passive:multiply yield of hutch by 2
		passive:multiply yield of coop by 2
		req:(cages>=10 or hutches>=10 or coops>=10)
		
	*buildingUpgrade2
		name:Prime grade hay
		desc:Not just for horses anymore!<//><b>Effect:</b><.>tilde cage production x2<.>tilde hutch production x2<.>tilde coop production x2
		icon:icons[2,0] icons[3,1]
		cost:100000 tildes
		passive:multiply yield of cage by 2
		passive:multiply yield of hutch by 2
		passive:multiply yield of coop by 2
		req:(cages>=50 or hutches>=50 or coops>=50)
		
	*buildingUpgrade3
		name:Shredded newspapers
		desc:You'd think they just poop on these, but they really enjoy reading the Sunday comics.<//><b>Effect:</b><.>tilde cage production x2<.>tilde hutch production x2<.>tilde coop production x2
		icon:icons[2,0] icons[3,2]
		cost:5000000 tildes
		passive:multiply yield of cage by 2
		passive:multiply yield of hutch by 2
		passive:multiply yield of coop by 2
		req:(cages>=100 or hutches>=100 or coops>=100)
		
	*buildingUpgrade4
		name:Pretty fences
		desc:Just the right size so your tildes can peek through but not hop over!<//><b>Effect:</b><.>tilde pen production x2<.>tilde meadow production x2
		icon:icons[2,0] icons[3,3]
		cost:50000 tildes
		passive:multiply yield of pen by 2
		passive:multiply yield of meadow by 2
		req:(pens>=10 or meadows>=10)
		
	*buildingUpgrade5
		name:Tilde playground
		desc:If your tildes are outside, they might as well get some exercise!<//><b>Effect:</b><.>tilde pen production x2<.>tilde meadow production x2
		icon:icons[2,0] icons[3,4]
		cost:5000000 tildes
		passive:multiply yield of pen by 2
		passive:multiply yield of meadow by 2
		req:(pens>=50 or meadows>=50)
		
	*buildingUpgrade6
		name:Tilde TVs
		desc:Televisions that broadcast tilde cartoons, tilde sitcoms, and tilde news bulletins.<//><b>Effect:</b><.>tilde village production x2<.>tilde city production x2
		icon:icons[2,0] icons[3,5]
		cost:1000000 tildes
		passive:multiply yield of village by 2
		passive:multiply yield of city by 2
		req:(villages>=10 or cities>=10)
		
	*buildingUpgrade7
		name:Wee little tilde cars
		desc:Your tildes drive around in these. How nice!<//><b>Effect:</b><.>tilde village production x2<.>tilde city production x2
		icon:icons[2,0] icons[3,6]
		cost:500000000 tildes
		passive:multiply yield of village by 2
		passive:multiply yield of city by 2
		req:(villages>=50 or cities>=50)
		
	*buildingUpgrade8
		name:Soothing moon crystals
		desc:Just really nice to be around.<//><b>Effect:</b><.>moon citadel production x2
		icon:icons[2,0] icons[3,7]
		cost:1000000000 tildes
		passive:multiply yield of citadel by 2
		req:10 citadels
		
	//golden carrot upgrades
	
	*goldenTouch
		name:Golden touch
		desc:The delicate art of finding vegetables made of precious metals.<//><b>Effect:</b><.>1% chance of gaining 1 golden carrot per tilde click
		icon:icons[2,5]
		cost:1 goldenCarrot
		req:1 goldenCarrot:earned
		
	*tildeHaste
		name:Tilde's haste
		desc:I'm late! I'm late! For a very important date!<//><b>Effect:</b><.>lucky tildes appear 30% more often
		icon:icons[2,6]
		passive:multiply frequency of luckyTilde by 0.7
		cost:5 goldenCarrots
		req:1 goldenCarrot:earned
	
	*independenceDay
		name:Independence day
		desc:Your tildes are making their first step towards declaring their independence from the oppressive shackles of pens and cages.<//><b>Effect:</b><.>unlocks new buildings
		icon:icons[2,7]
		cost:10 goldenCarrots
		req:5 goldenCarrots:earned
		
	*clover
		name:Clover
		desc:A delicious herb that tastes lucky.<//><b>Effect:</b><.>lucky tilde effects are 4 times more powerful
		icon:icons[2,8]
		cost:100 goldenCarrots
		req:50 goldenCarrots:earned
		
	*moonGardens
		name:Moon gardens
		desc:The royal botanists in your moon citadels have found new ways of cultivating plants in reduced gravity!<//><b>Effect:</b><.>moon citadels now produce 1 golden carrot every 100 seconds
		icon:icons[2,9]
		cost:100 goldenCarrots
		req:50 goldenCarrots:earned
		
Achievements
	*TEMPLATE
		on click:anim glow
		
	*tildeAchiev1
		name:Run tilde run
		desc:Have <b>1</b> tilde.
		req:1 tilde
		icon:icons[2,4] icons[0,2] icons[0,6]
	*tildeAchiev2
		name:Tildest home videos
		desc:Have <b>1000</b> tildes.
		req:1000 tildes
		icon:icons[2,4] icons[0,3] icons[0,6]
	*tildeAchiev3
		name:You got buns, hun
		desc:Have <b>1000000</b> tildes.
		req:10000000 tildes
		icon:icons[2,4] icons[0,4] icons[0,6]
		
	*clickAchiev1
		name:That tickles
		desc:Click the tilde <b>10</b> times.
		req:10 tildeButton clicks
		icon:icons[2,2] icons[0,2] icons[0,6]
	*clickAchiev2
		name:Don't squeeze me I'll fart
		desc:Click the tilde <b>100</b> times.
		req:100 tildeButton clicks
		icon:icons[2,2] icons[0,3] icons[0,6]
	*clickAchiev3
		name:You're cruising for a bruising, dude
		desc:Click the tilde <b>2000</b> times.
		req:2000 tildeButton clicks
		icon:icons[2,2] icons[0,4] icons[0,6]
		
	*tildePsAchiev1
		name:Be vewy vewy quiet
		desc:Produce <b>10</b> tildes per second.
		req:10 tildes per second
		icon:icons[2,3] icons[0,2] icons[0,6]
	*tildePsAchiev2
		name:Hop and a skip
		desc:Produce <b>1000</b> tildes per second.
		req:1000 tildes per second
		icon:icons[2,3] icons[0,3] icons[0,6]
	*tildePsAchiev3
		name:Go forth and multiply
		desc:Produce <b>100000</b> tildes per second.
		req:100000 tildes per second
		icon:icons[2,3] icons[0,4] icons[0,6]
		
	*carrotAchiev1
		name:Isn't it neat
		desc:Have <b>1</b> golden carrot.
		req:1 goldenCarrot
		icon:icons[0,1] icons[0,2]
	*carrotAchiev2
		name:All that glitters
		desc:Have <b>100</b> golden carrots.
		req:100 goldenCarrot
		icon:icons[0,1] icons[0,3]
	*carrotAchiev3
		name:Zero nutritional value
		desc:Have <b>1000</b> golden carrots.
		req:1000 goldenCarrot
		icon:icons[0,1] icons[0,4]
	
	*fortressAchiev
		name:Freedom!
		desc:Complete building the <b>freedom fortress</b>.<//>This is it. You beat the game!
		req:100 fortress
		icon:icons[3,8] icons[0,4]
		

